# usage:
#        > gnuplot
# gnuplot> call 'collimate.gp' 'inputData.dat' 'outputFile.pdf'

set term postscript portrait color solid 07
set output "collimate.ps"
set size 1.0, 1.0
set origin 0.0, 0.0
set multiplot
set style data lines

# plot Position
set size 1.00,0.25
set origin 0.0,0.75
set title "Position $0 "
set xlabel "hour of the day"
set ylabel "volts"
set yrange [*:*]
set xrange [*:*]
plot "$0" using 1:17 title "EW_dpos",\
     "$0" using 1:18 title "EW_apos",\
     "$0" using 1:22 title "NS_dpos",\
     "$0" using 1:23 title "NS_apos"

# plot dpos-apos #
set size 1.00,0.25
set origin 0.0,0.50
set title "dpos - apos $0 "
set xlabel "hour of the day"
set ylabel "volts"
set xrange [*:*]
set yrange [*:*]
#set yrange [-0.5:0.5]
plot "$0" using 1:($$17-$$18) title "EW dpos-apos",\
     "$0" using 1:($$22-$$23) title "NS dpos-apos"

# plot enable
set size 1.00,0.25
set origin 0.0,0.25
set title "enable"
set xlabel "hour of the day"
set ylabel "TTL Out"
set xrange [*:*]
set yrange [-1:2]
set style data linespoints
plot "$0" using 1:15 title "collimate enable" 

# plot enable
set size 1.00,0.25
set origin 0.0,0.00
set title "move"
set xlabel "hour of the day"
set ylabel "TTL Out"
set xrange [*:*]
set yrange [-1:2]
plot "$0" using 1:19 title "East",  \
     "$0" using 1:20 title "West",  \
     "$0" using 1:24 title "North", \
     "$0" using 1:25 title "South" 

unset multiplot

#########################################################333
##  Merge ps files & convert to pdf.
#########################################################333

! exec gs -dNOPAUSE -sDEVICE=pdfwrite -sOUTPUTFILE="$1" -dBATCH collimate.ps
! rm collimate.ps